###
### vim:ts=8 ai si sw=4 sta sm:
### $Id: myignore,v 1.1 2003/12/05 12:46:52 sec Exp sec $
### Ignore someone including replies.
###
#
# warning:	if you use nicksearch, load nicksearch before this script.

alias ig.help {
	echo *** This is the myignore Script.
	echo *** features include:
	echo *** + /ig <nick> - ignores nick including replies
	echo *** + /noig <nick> - unignores him again.
	echo *** + counts ignored lines in your status line.
}

eval if (!match(%+ig% $script_info)){
assign script_info $script_info+ig
};set client_info Sec$script_info


@ ig.space = [ ]
@ ig.he = 0
@ ig.re = 0

alias ig {
	^on ^public "$0 % *" ignorehe $$0-
	^on ^action "$0 % *" ignorehe $$0-
	# Hide text from nicksearch, too
	if (match(%+ns% $script_info)){
		^on ^public "$0 % *${ns.nick}*" ignorehe $$0-
		^on ^action "$0 % *${ns.nick}*" ignorehe $$0-
	}
	^on ^public "% % $0:*" ignorere $$0-
	^on ^public "% % $0,*" ignorere $$0-
	echo *** Mister $0 is now ignored, including replies...
}

alias noig {
	^on public -"$0 % *"
	^on action -"$0 % *"
	if (match(%+ns% $script_info)){
		^on public -"$0 % *${ns.nick}*"
		^on action -"$0 % *${ns.nick}*"
	}
	^on public -"% % $0:*"
	^on public -"% % $0,*"
	echo *** Mister $0 should now be unignored...
}

alias ignorehe {
	@ ig.he = ig.he + 1
	ignoredisp
}

alias ignorere {
	@ ig.re = ig.re + 1
	ignoredisp
}

alias ignoredisp {
	set status_user $ig.space<$ig.he,$ig.re>
}